Modme Forums

Buyable ending that replaced “game over” text?

Game Modding | Call of Duty: Black Ops 3 | Radiant


bubba443:

Currently using buyable ending from ugxmods. It has an option to change the game over text, but that feature doesnt seem to work for me. Does anyone have a buyable ending script/mod that can replace the "game over" text? Thanks!


Sleepy216:

Did you add your end game text to this at the top? It should work for you.

#define ENDGAME_CUSTOM_GAME_OVER    "your text here"
If you have ugx's timed gameplay installed, make sure your game over text isn't being set by that also


bubba443:

That line of code came with the ugxmods_buyable_ending.gsc

I tried changing it and it didnt work. It just used the default game over. I don't believe I have the timed gameplay installed.

/*
Created by Andy King (treminaor) for UGX-Mods.com. © UGX-Mods 2016
Please include credit if you use this script and do not distribute edited versions of it without my permission.
Instructions: https://confluence.ugx-mods.com/display/UGXMODS/BO3+|+Adding+Buyable+Ending+to+Zombiemode
Version 1.0 10/15/2016 12:55PM
*/

#using scripts\shared\flag_shared;
#using scripts\zm\_zm_score;
#define ENDGAME_WAIT_FOR_FLAG "" //if you want the ending to require a flag to be set from another script you have, enter the flag here.
#define ENDGAME_WAIT_FOR_NOTIFY "" //if you want the ending to require a level notify to be sent from another script you have, enter the notify string here.
#define ENDGAME_COST 0 //how much should it cost to end the game?
#define ENDGAME_CUSTOM_GAME_OVER "Lmao ez game I aint even sweatin" //Do you want to replace the "GAME OVER" text? Set it here. If you want the default game over text from zombies, set this to blank.
#define ENDGAME_CUSTOM_TRIGGER_HINT "You made it out... Press &&1 to end the game" //Customize the endgame trigger hintstring here. Cost will be appended automatically.
function autoexec endgame()
{
if(ENDGAME_WAIT_FOR_NOTIFY != "")
level.custom_game_over_hud_elem = &buyable_game_over;
ending = getEnt("ending", "targetname");
ending setCursorHint("HINT_NOICON");
if(ENDGAME_WAIT_FOR_FLAG != "")
{
level flag::wait_till(ENDGAME_WAIT_FOR_FLAG);
}
else if(ENDGAME_WAIT_FOR_NOTIFY != "")
{
level waittill(ENDGAME_WAIT_FOR_NOTIFY);
}
else
{
ending setHintString(ENDGAME_CUSTOM_TRIGGER_HINT + " [Cost: " + ENDGAME_COST + "]");
}
while(1)
{

ending waittill("trigger", player);
if(player.score < ENDGAME_COST)
{
wait 0.1;
player playsound("zmb_no_cha_ching");
continue;
}
player zm_score::minus_to_player_score(ENDGAME_COST);
player playsound("zmb_cha_ching");
break;
}
level notify("end_game");
}
function buyable_game_over(player, game_over, survived)
{
game_over.alignX = "center";
game_over.alignY = "middle";
game_over.horzAlign = "center";
game_over.vertAlign = "middle";
game_over.y -= 130;
game_over.foreground = true;
game_over.fontScale = 3;
game_over.alpha = 0;
game_over.color = ( 1.0, 1.0, 1.0 );
game_over.hidewheninmenu = true;
game_over SetText(ENDGAME_CUSTOM_GAME_OVER);
game_over FadeOverTime( 1 );
game_over.alpha = 1;
if ( player isSplitScreen() )
{
game_over.fontScale = 2;
game_over.y += 40;
}
}

Did you add your end game text to this at the top? It should work for you.
#define ENDGAME_CUSTOM_GAME_OVER    "your text here"
If you have ugx's timed gameplay installed, make sure your game over text isn't being set by that also


Sleepy216:

/*
Created by Andy King (treminaor) for UGX-Mods.com. &#169; UGX-Mods 2016
Please include credit if you use this script and do not distribute edited versions of it without my permission.
Instructions: https://confluence.ugx-mods.com/display/UGXMODS/BO3+|+Adding+Buyable+Ending+to+Zombiemode
Version 1.0 10/15/2016 12:55PM
*/

#using scripts\shared\flag_shared;
#using scripts\zm\_zm_score;
#define ENDGAME_CUSTOM_GAME_OVER "Lmao ez game I aint even sweatin" //Do you want to replace the "GAME OVER" text? Set it here. If you want the default game over text from zombies, set this to blank.
#define ENDGAME_CUSTOM_TRIGGER_HINT "You made it out... Press &amp;&amp;1 to end the game" //Customize the endgame trigger hintstring here. Cost will be appended automatically.

function autoexec endgame()
{
    level.custom_game_over_hud_elem = &amp;buyable_game_over;
    ending = getEnt("ending", "targetname");
    ending setCursorHint("HINT_NOICON");

    ending setHintString( ENDGAME_CUSTOM_TRIGGER_HINT );


    ending waittill("trigger", player);
    level notify("end_game");
}

function buyable_game_over(player, game_over, survived)
{
    game_over.alignX = "center";
    game_over.alignY = "middle";
    game_over.horzAlign = "center";
    game_over.vertAlign = "middle";
    game_over.y -= 130;
    game_over.foreground = true;
    game_over.fontScale = 3;
    game_over.alpha = 0;
    game_over.color = ( 1.0, 1.0, 1.0 );
    game_over.hidewheninmenu = true;
    survived.alignX = "center";
    survived.alignY = "middle";
    survived.horzAlign = "center";
    survived.vertAlign = "middle";
    survived.color = ( 1.0, 1.0, 1.0 );
    survived.foreground = true;
    survived.fontScale = 2;
    survived.alpha = 0;
    survived.y -= 95;
    survived.hidewheninmenu = true;
    game_over SetText(ENDGAME_CUSTOM_GAME_OVER);
    game_over FadeOverTime( 1 );
    survived FadeOverTime( 1 );
    survived.alpha = 1;
    game_over.alpha = 1;
    if ( player isSplitScreen() )
    {
        game_over.fontScale = 2;
        game_over.y += 40;
    }
}

I tried this out and it worked, give it a shot and let me know how it goes!


bubba443:

It works! Thanks so much!